betti

betti C -- display the graded Betti numbers for a ChainComplex C.

betti f -- display the graded Betti numbers for a Matrix f, regarding it as a complex of length one.

betti G -- display the graded Betti numbers for the matrix of generators of a GroebnerBasis G.

Here is a sample display:

i1 : R = ZZ/101[a..h]



o1 = R



o1 : PolynomialRing

i2 : p = genericMatrix(R,a,2,4)



o2 = {0} | a c e g |

     {0} | b d f h |



             2       4

o2 : Matrix R  <--- R

i3 : q = generators gb p



o3 = {0} | g e c a 0     0     0     0     0     0     |

     {0} | h f d b fg-eh dg-ch bg-ah de-cf be-af bc-ad |



             2       10

o3 : Matrix R  <--- R

i4 : C = resolution cokernel leadTerm q



      2      10      14      7      1

o4 = R  <-- R   <-- R   <-- R  <-- R

                                   

     0      1       2       3      4



o4 : ChainComplex

i5 : betti C



o5 = total: 2 10 14 7 1

         0: 2 4  6  4 1

         1: . 6  8  3 .



o5 : Net

The top row of the display indicates the ranks of the free module C_j in column j. The entry below in row i column j gives the number of basis elements of degree i+j.

If these numbers are needed in a program, one way to get them is with tally.

i6 : degrees C_2



o6 = {{2}, {2}, {2}, {2}, {2}, {2}, {3}, {3}, {3}, {3}, {3}, {3}, {3}, {3}}



o6 : List

i7 : t2 = tally degrees C_2



o7 = Tally{{2} => 6}

           {3} => 8



o7 : Tally

i8 : peek t2



o8 = Tally{{2} => 6}

           {3} => 8



o8 : Net

i9 : t2_{2}



o9 = 6

i10 : t2_{3}



o10 = 8